#!/usr/bin/env perl
# ts=4
# do the hard work for an MFC
# last update 2012-05-30

use strict;
use warnings;
use File::Basename;

my $prog = basename($0);
my ($rev, $remoterepo, $revdir, $localdir, $localrepo);
my ($log, $mrgd, $info, $stat, $minf, $diff);

my $reportdir = '/tmp';

sub usage {
	print $#ARGV;
	print <<USAGE;
$prog
usage: $prog -h
       $prog revision remote-repo dir localrepo

       Example: MFC rev 235842
       from remote "head" directory "bin/uuidgen"
       to local directory "stable/9/bin/uuidgen"

       % $prog 235842 head bin/uuidgen stable/9
USAGE
	exit 0;
}

sub getcmdline {
	usage unless $#ARGV == 3;
	($rev, $remoterepo, $revdir, $localdir) = @ARGV;
	$remoterepo = "svn+ssh://svn.freebsd.org/base/$remoterepo/$revdir";
	$localrepo  = "$localdir/$revdir";
}

sub precheck {
	print "checking local repository\n";
	# do quick tests first
	unless ( -d $localrepo ) {
		print "local path '$localrepo' not found\n";
		print "in the wrong directory?\n";
		exit;
	}
	my $unmod = `svn stat $localrepo`;
	if ( $unmod ) {
		print "local repository has been modified\n";
		print "cannot continue\n\n";
		print $unmod;
		exit;
	}
	my $merged = `svn propget -R svn:mergeinfo $localrepo | grep $rev`;
	if ( $merged =~ s/$rev/[[[${rev}]]]/ ) {
		print "\nrev $rev already merged according to svn propget:\n";
		print "$merged\n";
		exit;
	}
	print "checking remote repository\n";
	my $revexist = `svn info -r $rev $remoterepo`;
	if ( $revexist =~ /unable to connect|unknown hostname|no repository found/i ) {
		print "could not connect to remote repo\n\n";
		print $revexist;
		exit;
	}
	if ( $revexist =~ /no such revision/i ) {
		print "rev $rev not found on remote\n\n";
		print $revexist;
		exit;
	}
	print "checking eligible revisions\n";
	my $elig = `svn --show-revs=eligible mergeinfo $remoterepo $localrepo`;
	unless ( $elig =~ /$rev/ ) {
		print "rev $rev not eligible for MFC\n\n";
		print "svn --show-revs=eligible mergeinfo $remoterepo $localrepo\n";
		print "$elig";
		exit;
	}
}

sub mergeit {
	print "merging\n";
	$mrgd = `svn merge -c $rev $remoterepo $localrepo`;
}

sub writereport {
	my $localpath = $localdir;
	$localpath =~ tr/\//-/;
	my $fname = "$reportdir/$localpath-$rev.txt";
	print "writing report to $fname\n";
	my $break = '-' x 20 . "\n";
	open(my $fh, '>', $fname) or die $!;
	print $fh "merging r$rev of $remoterepo\n";
	print $fh "  to $localdir\n\n";
	# print $fh $break;
	# print $fh "svn merge -c $rev $remoterepo $localrepo\n";
	# print $fh $mrgd, "\n\n";
	print $fh $break;
	print $fh "% svn info $localrepo\n";
	print $fh $info, "\n\n";
	print $fh $break;
	print $fh "% svn stat $localrepo\n";
	print $fh $stat, "\n\n";
	print $fh $break;
	print $fh "% svn propget -R svn:mergeinfo $localrepo\n";
	print $fh $minf, "\n\n";
	print $fh $break;
	print $fh "% svn diff $localrepo\n";
	print $fh $diff, "\n\n";
	print $fh $break;
	print $fh "to commit:\n\n";
	print $fh " % svn commit $localrepo\n\n\n";
	print $fh $break;
	print $fh "% svn log -r$rev $remoterepo\n";
	print $fh "(commit message)\n\n";
	print $fh "MFC r$rev\n\n";
	print $fh $log;
	close $fh or die $!;
}

sub collectinfo {
	print "collecting information\n";
	$log  = `svn log -r$rev $remoterepo`;
	$log  =~ s/^.*\n.*\n.*\n//;		# remove first three lines of svn log
	$info = `svn info $localrepo`;
	$stat = `svn stat $localrepo`;
	$minf = `svn propget -R svn:mergeinfo $localrepo`;
	$diff = `svn diff $localrepo`;
}

sub showinfo {
	print "local merge complete\n";
	print "to commit:\n\n";
	print "  svn commit $localrepo\n\n";
	print "commit message:\n\n";
	print "MFC r$rev:\n\n";
	print "$log";
}

# main

getcmdline;
precheck;
mergeit;
collectinfo;
writereport;
showinfo;